开启辅助访问
 找回密码
 注册帐号

扫一扫,访问微社区

教程分享

关注:577

当前位置:游戏蛮牛 技术专区 教程分享

查看: 586|回复: 1

[自学总结] Unity Shaders——SurfaceShader(六)混合纹理

[复制链接]  [移动端链接]
5熟悉之中
939/1000
排名
3170
昨日变化
3

188

主题

224

帖子

939

积分

Rank: 5Rank: 5

UID
128653
好友
0
蛮牛币
2020
威望
0
注册时间
2015-11-12
在线时间
124 小时
最后登录
2017-2-22
发表于 2016-10-12 11:25:46 | 显示全部楼层 |阅读模式

马上注册,结交更多好友,享用更多功能,让你轻松玩转社区。

您需要 登录 才可以下载或查看,没有帐号?注册帐号

x

版本:.3

纹理混合就是将几张纹理重合在一起显示。最常见的情形是地形纹理。混合纹理可以优化性能,这样只要渲染一次混合后的纹理即可,而不必渲染多次。
接下来要介绍的就是如何混合纹理制作地形着色器:

先准备几张贴图:

1.jpg

2.png

3.jpg

4.jpg

这几张就是要混合图片。
我们还需要下面这张图片,这张图片就决定了图片是如何混合的:

5.jpg

(可以先转到后面看效果)
好了,上代码(我还是直接贴全部吧):

[C#] 纯文本查看 复制代码
Shader "Custom/Textures" {
    Properties {  
        _MainTint ("Diffuse Tint", Color) = (1,1,1,1)  
          
        //Add the properties below so we can input all of our textures  
        _ColorA ("Terrain Color A", Color) = (1,1,1,1)  
        _ColorB ("Terrain Color B", Color) = (1,1,1,1)  
        _RTexture ("Red Channel Texture", 2D) = ""{}  
        _GTexture ("Green Channel Texture", 2D) = ""{}  
        _BTexture ("Blue Channel Texture", 2D) = ""{}  
        _ATexture ("Alpha Channel Texture", 2D) = ""{}  
        _BlendTex ("Blend Texture", 2D) = ""{}  
    }  
    SubShader {  
        Tags { "RenderType"="Opaque" }  
        LOD 200  
          
        CGPROGRAM  
        #pragma surface surf Lambert  
        // Important!
        #pragma target 4.0
  
        float4 _MainTint;  
        float4 _ColorA;  
        float4 _ColorB;  
        sampler2D _RTexture;  
        sampler2D _GTexture;  
        sampler2D _BTexture;  
        sampler2D _ATexture;  
        sampler2D _BlendTex;  
  
        struct Input {  
            float2 uv_RTexture;
            float2 uv_GTexture;  
            float2 uv_BTexture;  
            float2 uv_ATexture;  
            float2 uv_BlendTex;  
        };  
  
        void surf (Input IN, inout SurfaceOutput o) {  
            //Get the pixel data from the blend texture  
            //we need a float 4 here because the texture   
            //will return R,G,B,and A or X,Y,Z, and W  
            float4 blendData = tex2D(_BlendTex, IN.uv_BlendTex);  
              
            //Get the data from the textures we want to blend  
            float4 rTexData = tex2D(_RTexture, IN.uv_RTexture);  
            float4 gTexData = tex2D(_GTexture, IN.uv_GTexture);  
            float4 bTexData = tex2D(_BTexture, IN.uv_BTexture);  
            float4 aTexData = tex2D(_ATexture, IN.uv_ATexture);  
              
            //No we need to contruct a new RGBA value and add all   
            //the different blended texture back together  
            float4 finalColor;  
            finalColor = lerp(rTexData, gTexData, blendData.g);  
            finalColor = lerp(finalColor, bTexData, blendData.b);  
            finalColor = lerp(finalColor, aTexData, blendData.a);  
            finalColor.a = 1.0;  
              
            //Add on our terrain tinting colors  
            float4 terrainLayers = lerp(_ColorA, _ColorB, blendData.r);  
            finalColor *= terrainLayers;  
            finalColor = saturate(finalColor);  
                  
            o.Albedo = finalColor.rgb * _MainTint.rgb;  
            o.Alpha = finalColor.a;  
        }  
        ENDCG  
    }   
    FallBack "Diffuse"  
}  


1、注意我标注了Important!的那行代码,我们在Input结构体里加入了5个UV坐标,如果没写#pragma target 4.0,在Input结构体里加入3个以上的UV坐标,会报错Too many texture interpolators would be used for ForwardBase pass。要么就减少Input里面的UV坐标,那么就加上#pragma target 4.0。在这个例子中,几张贴图的纹理坐标是可以共用的,因为它们的Tilling和Offset的一样,坐标是一样的,也可以在后面的代码中使用同一个坐标。不过如果想每张纹理都有自己的UV坐标以便受到更多的控制的话,那就设置目标编译模型为4.0.(不过好像在4.X的版本里加入多个UV坐标不会报错)

2、默认你已经看过了前面的文章了,所以大部分代码不需要解释。需要解释的就是lerp函数。lerp就是线性插值。lerp(a,b,f)返回(1-f)*a+b*f。当f为1的时候,就是b值,当f为0时,就是a值,当f为0.5时,就是0.5a+0.5b,也就是f的值越大,a、b混合的值中b的值越大。

3、明白了lerp函数,颜色混合的那几行代码也就很容易理解了。第一句就是将BlendTexture中的绿色通道当作f值,也就BlendTexture中越绿的地方,gTexture的值越多,表现就是gTexture纹理越明显。剩下的也是同样的道理。

效果

按下面的贴图顺序给纹理赋值:

6.jpg

效果是这样的:

7.jpg

当然贴图顺序是可以更换的,那样会得到不同的效果。
我们看到,在BlendTexture中发红的区域,显示的红色通道贴图的石子,发绿的区域显示的是绿色通道的石子加泥土,发蓝的区域则是蓝色通道中的草地,一些带透明的区域显示的则是透明通道中贴图颜色。


回复

使用道具 举报

7日久生情
2222/5000
排名
310
昨日变化
3

0

主题

129

帖子

2222

积分

Rank: 7Rank: 7Rank: 7Rank: 7

UID
70407
好友
0
蛮牛币
3200
威望
0
注册时间
2015-1-22
在线时间
847 小时
最后登录
2017-2-21
QQ
发表于 2016-10-12 14:25:55 | 显示全部楼层
不错 但是先使用PS先混合是否更节约资源?毕竟地形贴图需要无缝处理

回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 注册帐号

本版积分规则

快速回复 返回顶部 返回列表